Δ[u_]:=Laplacian[u[x,y],{x,y}];
Ω=RegionDifference[ImplicitRegion[0<x<Pi&& 0<y<Pi +x (Pi-x)/Pi,{x,y}], Disk[{Pi/3,Pi/2},Pi/4]];
(* numerical Robin ((∂_n)u=γu)  eigenvalues and contour plots of eigenfunctions for Ω *)
γ=2;
{eval, efun}=NDEigensystem[-Δ[u]+NeumannValue[γ u[x,y],True], u[x,y],{x,y}∈Ω,6];
GraphicsGrid[Table[ContourPlot[efun[[3(i-1)+j]],{x,0,Pi},{y,0,5Pi/4},
Contours->{-0.5,-0.25,0,0.25,0.5},RegionFunction->Function[{x,y,z},{x,y}∈Ω],Frame->False,AspectRatio->Automatic,BoundaryStyle->Thick,PlotLabel->"λ="<>ToString[eval[[3(i-1)+j]]]
],{i,1,2},{j,1,3}],ImageSize->Large]