Δ[u_]:=Laplacian[u[x,y],{x,y}];
Ω=RegionDifference[ImplicitRegion[0<x<Pi&& 0<y<Pi +x (Pi-x)/Pi,{x,y}], Disk[{Pi/3,Pi/2},Pi/4]];
(* numerical Zaremba eigenvalues and eigenfunctions for Ω *)
(* Dirichlet condition on all sides except Neumann on the curved upper side *)
{eval, efun}=NDEigensystem[{-Δ[u],DirichletCondition[u[x,y]==0,y<=Pi]}, u[x,y],{x,y}∈Ω,6];
GraphicsGrid[Table[Plot3D[efun[[3(i-1)+j]],{x,0,Pi},{y,0,5Pi/4},RegionFunction->Function[{x,y,z},{x,y}∈Ω],
BoundaryStyle->Thick,Boxed->False,Axes->True,AxesOrigin->{0,0,0},AspectRatio->Automatic,
Ticks->None,PlotLabel->"λ="<>ToString[eval[[3(i-1)+j]]]],{i,1,2},{j,1,3}]]